Textkette inkl. bestimmtem Bereich?

[OSO]

Hallo,

ich habe ein etwas verzwicktes Problem, das ich mit einer Formel lösen möchte.

Wert 1	Wert 2	Textkette
ABC	123	123 456 789 101112
	456
	789
	101112
DEF	131415	141415 161718 192021 222324
	161718
	192021
	222324
GHI	252627	252627 282930 313233
	282930
	313233

Aktuell habe ich diese Formel:

=WENN(A2<>"";(TEXTKETTE(B2:B16)))

Das bedeutet, in der Spalte "Textkette" wird nur ein Wert ausgegeben, wenn in der Spalte "Wert 1" ein Wert vorhanden ist.
Allerdings soll die Formel noch erweitert werden, sodass nicht ein fest definierter Bereich "B2:B16" verkettet wird, sondern immer ein Bereich "zwischen" zwei Werten in der Spalte A.
Das heißt von ABC bis vor (also ohne) DEF, dann wieder von DEF bis vor GHI, usw.

Lässt sich also in der Formel =WENN(A2<>"";(TEXTKETTE(B2:B16)))  "B2:B16" durch eine entsprechende weitere Formel ersetzen?

Vielen Dank und beste Grüße

[{Boris}]

Hi,

wenn die Werte in der Spalte A immer TEXTE sind, dann in C2:

Code:

=WENN(A2="";"";TEXTKETTE(B2:INDEX(B3:B$500;VERGLEICH("*";A3:A$500;0)-1;)))

und runterkopieren.

WICHTIG: Unter dem allerletzten Eintrag muss in Spalte A noch irgendein Text als "Marker" stehen, damit auch die letzte Textkette gebildet werden kann.

VG, Boris

[{Boris}]

Hi,

mit einer Hilfsspalte lässt sich das auch einfach mit der FILTER-Funktion lösen.

Hilfsspalte C, dort in

C2:
=WENN(A2="";C1;A2)
und bis zum Ende runterkopieren.

D2:
=WENN(A2="";"";TEXTKETTE(FILTER(B$2:B$500;C$2:C$500=A2)))
und ebenfalls runterkopieren.

Voraussetzung: Es gibt keine doppelten Einträge in Spalte A.

Alternativformel für D2 wäre noch:
=WENN(A2="";"";TEXTKETTE(WENN(C$2:C$500=A2;B$2:B$500;"")))

VG, Boris

[OSO]

Super, vielen Dank euch! Hat mir sehr geholfen.