+- Office-Fragen.de (https://office-fragen.de)
+-- Forum: Microsoft Office (https://office-fragen.de/forum-1.html)
+--- Forum: Excel (https://office-fragen.de/forum-2.html)
+--- Thema: Zeile löschen ohne Formel und Bezüge zu zerstören (/thread-29242.html)
Zeile löschen ohne Formel und Bezüge zu zerstören - Selli - 07.06.2025
Schönen guten Morgen,
bräuchte wiedermal nach langer Zeit Eure Hilfe bitte.
Wie bekomme ich es hin, wenn ich eine Zeile lösche, das 2 Bezüge immer gleich bleiben.
Trotz $ Zeichen ändert sich immer ein Bezug.
Verwende folgende Formel um Zeitabstände zu messen.
=WENN(($A$25-$A$1)*1440<10,35;"ja";"nein") / steht in Zeile 25
=WENN(($A$26-$A$2)*1440<10,35;"ja";"nein") / steht in Zeile 26
![[Bild: Excel-Bild.png]](https://i.ibb.co/HfZFFLjw/Excel-Bild.png)
Wenn ich nun Zeile 26 Lösche, dann sieht die Formel wie folgt aus:
=WENN(($A$26-$A$3)*1440<10,35;"ja";"nein")
Was muss ich nun machen, das die Formel wie oben angegeben gleich bleibt.
$A$26 der bleibt erhalten
$A$3 ist nicht gewollt, nach dem löschen soll dieser $A$2 bleiben.
Nach einigem lesen und probieren komme ich nicht weiter
Mein Hauptproblem ist, das es später über 2000 Zeilen sind, wo ich in 24er Blöcke die Zeitabstände einstellen will.
Ich muss gewährleisten, das der Zeitabstand zwischen Zeile 25 und Zeile 1 nicht unter 10,35 min. liegt.
Dann wiederum den Zeitabstand von Zeile 49 und Zeile 25 und alles was da zwischen liegt . Wie erwähnt, in 24er Blöcke .
Daher muss ich Zeilen löschen, wenn es mit dem Zeitabstand nicht passt. So rutschen die Zeilen von unten nach oben und dabei soll bei gleich bleibender
Formel die Stelle erneut berechnet werden, bis es am Ende überall passt.
Hoffe ich konnte mein Problem erklären.
LG
Selli
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - DL - 07.06.2025
Moin
Laß mal die $-Zeichen weg.
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - Selli - 07.06.2025
Wenn ich die $ weglasse haut es auch nicht hin. Das war mein ertser Versuch gewesen.
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - DL - 07.06.2025
Anderer Vorschlag.
Code:
=LET(
bis;ZEILE();
von;bis-24;
diff;(INDEX(A:A;bis)-INDEX(A:A;von))*1440;
ergebnis;WENN(diff<10,35;"ja";"nein");
diff)RE: Zeile löschen ohne Formel und Bezüge zu zerstören - Flotter Feger - 08.06.2025
Hallo Detlef,
in deiner Formel ist ein Fehler ... das letzte Argument ist falsch benannt.
=LET(bis;ZEILE();von;bis-24;diff;(INDEX(A:A;bis)-INDEX(A:A;von))*1440;ergebnis;WENN(diff<10,35;"ja";"nein");ergebnis)
Und für Excel kleiner 365/2021/2024, lautet die Formel so ...
=WENN(((INDEX(A:A;ZEILE())-INDEX(A:A;ZEILE()-24))*1440)<10,35;"ja";"nein")
Sabina
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - DL - 08.06.2025
Danke für den Hinweis.
Ich hatte die Formel zwischenzeitlich auf ein Zwischenergbnis eingestellt und vergessen vor dem Posten wieder rückgängig zu machen.
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - {Boris} - 09.06.2025
Hi,
die ganz sichere Variante (sowohl bezüglich Löschen von Zeilen als auch Spalten) ist die Verwendung von INDIREKT:
=INDIREKT("A2")
liefert immer den Wert aus A2 - egal was Du wie löschst. "A2" ist ein TEXT - daher sind auch die $-Zeichen obsolet.
Einziger winziger "Nachteil" von IDIREKT: Die Mappe wird dadurch volatil. Mich persönlich stört das nicht besonders, aber bevor wieder ein Aufschrei kommt ;-), kannst Du das auch mit INDEX lösen:
=INDEX(A:A;2)
liefert auch immer den Wert aus A2 - egal, wie viele Zeilen Du löschst. Nur gegen das Löschen von Spalten ist diese Variante nicht immun: Wird Spalte A gelöscht, dann verliert die Formel ihren Bezug und meckert gleichlautend mit #BEZUG!.
Das nur mal als allgemeine Hinweise.
VG, Boris
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - HKindler - 09.06.2025
Hi,
wenn auch das Löschen der Spalte A egal sein soll, dann nimmt man halt
=INDEX(1:1048576;2;1)
oder
=INDEX(A:XFD);2;1)
Was Excel sofort in die erste Formel mit den Zeilen statt Spalten umwandelt. Trotzdem verwende ich bei so etwas (das ganze Blatt ansprechen) immer die Spaltenvariante, da ich mit einfach nicht merken kann, was denn nun die letzte Zeile nochmals war.
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - Selli - 16.06.2025
Danke für die vielen Antworten. wegen einer Grippe kam ich leider noch zu nix.
Werde die tage alles testen, was nicht Office 365 ist und gebe danach mein Feedback.
Nochmal vielen Dank :-)
RE: Zeile löschen ohne Formel und Bezüge zu zerstören - Selli - 17.06.2025
Nochmal Hallo an alle Helfer.
Da ich tatsächlich noch mit Office 2007 arbeite, war die Lösung von Sabina bei mir voll zutreffend und Funktioniert wie gewünscht.
Danke auch an Detlef, auch wenn ich kein Office 365 habe, kommt man automatisch auf andere Ideen, sowie man die Formel sieht :-)
Die Formeln von Boris und Helmut brauche ich Aktuell nicht, werde diese mir aber abspeichern. Wer weis wann ich mal ne Spalte löschen muss :-)
Nochmals vielen dank. Ihr seit Super !
